Greetings,

My VB5.0 APP is receiving a list of files to process via drag-and drop from
explorer.
My VB app must then call a legacy DOS program to filter these files.
the DOS app does not understand long file names.  Is there a function or
API call that will perform the conversion?

I know I can take the first 6 char and append ~1, but this will not work
100% of
the time. (The case of files with the same name beyond the 8.3 format.

Any ideas would be appreciated.
Brian

Dear Brian,

here is a piece of code I wrote some time ago, please feel free to use it

Syntax: <shortfilename> = MakeDOSName(<longfilename>)

Private Const MAX_PATH As Integer = 260

Private Declare Function GetShortPathName Lib "kernel32" Alias
"GetShortPathNameA" _
                (ByVal lpszLongPath As String, _
                 ByVal lpszShortPath As String, _
                 ByVal cchBuffer As Long) As Long

Private Function MakeDOSName(ByVal szLongFileName As String) As String
    Dim lAPIResult As Long

    ' Initialize string w/empty spaces
    MakeDOSName = Space$(MAX_PATH)

    ' Call WinAPI
    lAPIResult = GetShortPathName(szLongFileName, _
                                  MakeDOSName, _
                                  Len(MakeDOSName))

    If (lAPIResult) Then
        ' we need to strip the string delimiter
        MakeDOSName = Mid$(MakeDOSName, 1, lAPIResult)
    End If

    ' All set
    MakeDOSName = Trim$(MakeDOSName)
End Function

Hope this helps,
Luca G. Fontanarosa
Sr. Software Engineer

Private Declare Function OSGetShortPathName& Lib "kernel32" Alias "GetShortPathNameA" (ByVal lpszLongPath$, ByVal lpszShortPath$,
ByVal cchBuffer&)

Public Function ShortFileName(ByVal LongFileName As String) As String
' Purpose:     Changes long filenames to it's equivalent short filename (in DOS 8.3 format).
' Arguments:   LongName (name of file)
' Returns:     Short filename
' Notes:       The file and directory must exist for this to work.
'              32-Bit function
   Dim Buffer$
   Dim Result&

   LongFileName = Trim$(LongFileName)
   On Error Resume Next
   If Len(LongFileName) Then
      Buffer$ = Space$(128)
      Result& = OSGetShortPathName&(LongFileName, Buffer$, Len(Buffer$))
      ShortFileName = IIf(Result& > 0, Left$(Buffer$, Result&), LongFileName$)
   End If
   On Error GoTo 0
End Function

Paul Schirf