' ====================
I ran across
Private Declare Function MakeSureDirectoryPathExists Lib "IMAGEHLP.DLL" _
(ByVal DirPath As String) As Long

    bResult = MakeSureDirectoryPathExists(sPathIn)

but I am not sure if that is appropriate since what is IMAGEHLP.DLL?

' =======================
I tried working with

Private Type SECURITY_ATTRIBUTES
    nLength As Long
    lSecurityDescriptor As Long
    bInheritHandle As Long
End Type
'
Private Declare Function CreateDirectory Lib "kernel32" Alias
"CreateDirectoryA" _
    (ByVal lpPathName As String, _
    lpSecurityAttributes As SECURITY_ATTRIBUTES) As Long
'

Private Function CreateFolder(sFolder As String) As Boolean

    On Error GoTo CreateFolderErr

    Dim tSA As SECURITY_ATTRIBUTES
    Dim lRet As Long

    tSA.nLength = LenB(tSA)

    ' If the function succeeds, the return value is nonzero.
    lRet = CreateDirectory(sFolder, tSA)   ' returns zero on failure

    CreateFolder = (lRet <> 0) ' true on success

CreateFolderExit:
    Exit Function

CreateFolderErr:
    Resume CreateFolderExit

End Function 'CreateFolder

Not sure how to deal with this since first I need to know how to check if
partial path is there.  What do I use to check if partial path exists?

   ' http://msdn.microsoft.com/en-us/library/bb762131(VS.85).aspx
   Private Declare Function SHCreateDirectoryExW Lib "shell32" (ByVal hWnd As Long,
ByVal lpszPath As Long, ByVal lpSA As Long) As Long

   Public Function PathMakeDirs(ByVal Path As String) As Boolean
      Dim nRet As Long
      ' Potential error codes.
      Const ERROR_SUCCESS As Long = 0&
      Const ERROR_FILENAME_EXCED_RANGE As Long = 206&
      Const ERROR_BAD_PATHNAME As Long = 161&
      Const ERROR_PATH_NOT_FOUND As Long = 3&
      Const ERROR_FILE_EXISTS As Long = 80&
      Const ERROR_ALREADY_EXISTS As Long = 183&
      Const ERROR_CANCELLED As Long = 1223&
      ' Requires v5.0 of Shell32.dll...
      nRet = SHCreateDirectoryExW(0&, StrPtr(Path), 0&)
      ' Treat "already exists" as success...
      PathMakeDirs = _
         (nRet = ERROR_SUCCESS) Or _
         (nRet = ERROR_FILE_EXISTS) Or _
         (nRet = ERROR_ALREADY_EXISTS)
   End Function

One thing that bothers me though, is the apparent limit on path length.

   "A pointer to a null-terminated string specifying the fully qualified path of the
directory. This string is of maximum length of 248 characters, including the
terminating null character."

That doesn't make sense because the MakeSureDirectoryPathExists docs state:

   "This function does not support Unicode strings. To specify a Unicode path, use
the SHCreateDirectoryEx function."

And Unicode paths can be *much* longer than that!  I tested it, and indeed, it fails
at that point.  Not sure what the best remedy there is.  There may indeed be no
shortcut here.
--
.NET: It's About Trust!
 http://vfred.mvps.org