My code is listed bellow but returns the error

`Can`t start your application: The workgroup information file is
missing or opened exclusivly by another users ..`

Any help would be of interest .. especialy a working code example and
database.

Private Sub Command1_Click()

Dim conn As New ADODB.Connection
Dim cmd As New ADODB.Command
Dim rs As New ADODB.Recordset
' Open Connection

conn.Open "provider=Microsoft.Jet.OLEDB.3.51;data
source=c:\temp\t2supprt.mdb;User ID=Admin;Password=xxxx"
' SQL ?
Set cmd.ActiveConnection = conn
cmd.CommandText = "SELECT * from tblClient"
' Cursor Location
' rs.CursorLocation = tblClient
rs.Open cmd, , adOpenStatic, adLockBatchOptimistic
' Step 4
rs.Sort = "SearchName"
rs.Filter = "Telephone LIKE '0171*'"
rs.MoveFirst
Do While Not rs.EOF
    Debug.Print "Name: " & rs!SearchName & "Phone: " & rs!Telephone &
vbCr
    rs.MoveNext
Loop
' Step 5

conn.BeginTrans

'Step 6, part A
On Error GoTo ConflictHandler
rs.UpdateBatch
On Error GoTo 0

conn.CommitTrans
Exit Sub

'Step 6, part B
ConflictHandler:
rs.Filter = adFilterConflictingRecords
rs.MoveFirst
Do While Not rs.EOF
    Debug.Print "Conflict: Name: " & rs!SearchName & "Phone: " &
rs!Telephone & vbCr
    rs.MoveNext
Loop
conn.Rollback
Resume Next
End Sub

you are not pointing to the Jet system database that controls the
security information. Is the database actually secured? here's an
example of creating a connection on a secured database:

  Dim strConn As String
  Dim cnn As ADODB.Connection
  Dim rst As ADODB.Recordset

  strConn = "User ID=xxx;Password=yyy;" & _
    "Data Source=g:\vbfms\taagent32\code\taagnt32.mdb;" & _
    "Provider=Microsoft.Jet.OLEDB.3.51;" & _
    "Jet OLEDB:System database=g:\vbfms\taagent32\code\taasys32.mdw;"

  Set cnn = New ADODB.Connection
  cnn.ConnectionString = strConn
  cnn.Open

  Set rst = New ADODB.Recordset
  rst.ActiveConnection = cnn
  rst.Open "tblSettings"
  Do Until rst.EOF
    Debug.Print rst(0)
    rst.MoveNext
  Loop

-- Jim Ferguson, FMS
   http://www.fmsinc.com