Is there a way to make the close box not an option on a winform without
getting rid of the minimize and Maximize buttons too?  If not, how does one
nullify or trap for the clicking of the x (close) button on a winform.

Hello Woody,

\\\
Private Declare Function GetSystemMenu Lib "user32.dll" ( _
    ByVal hWnd As IntPtr, _
    ByVal bRevert As Int32 _
) As IntPtr
Private Declare Function GetMenuItemCount Lib "user32.dll" ( _
    ByVal hMenu As IntPtr _
) As Int32
Private Declare Function DrawMenuBar Lib "user32.dll" ( _
    ByVal hWnd As IntPtr _
) As Int32
Private Declare Function RemoveMenu Lib "user32.dll" ( _
    ByVal hMenu As IntPtr, _
    ByVal nPosition As Int32, _
    ByVal wFlags As Int32 _
) As Int32

Private Const MF_BYPOSITION As Int32 = &H400
Private Const MF_REMOVE As Int32 = &H1000

Private Sub RemoveCloseButton(ByVal frmForm As Form)
    Dim hMenu As IntPtr, n As Int32
    hMenu = GetSystemMenu(frmForm.Handle, 0)
    If Not hMenu.Equals(IntPtr.Zero) Then
        n = GetMenuItemCount(hMenu)
        If n > 0 Then
            RemoveMenu(hMenu, n - 1, MF_BYPOSITION Or MF_REMOVE)
            RemoveMenu(hMenu, n - 2, MF_BYPOSITION Or MF_REMOVE)
            DrawMenuBar(Me.Handle)
        End If
    End If
End Sub
///

Sample usage:

\\\
RemoveCloseButton(Me)
///

Regards,
Herfried K. Wagner

Woody,

Unfortunately, you cannot do away with the "x" (close) button on a WinForm.
But, you can definitely handle it thru code.

The form has a Form.Closing event, in which you can cancel the closing
process. It receives an arg of tye CancelEventArgs. Set the "Cancel"
property of the CancelEventArgs variable to true and your form will remain
open.

But then, the question is, how do you "really" close it? For this, you will
have to come up with a logic in the Form.Closing event and do the needful.

Hope this helps.

Ajay Singala [Synergetics].

I realize this question is real basic but I am still shakey with VS.  What
is the syntax for writing the addHandler in this case?  I tried something
like:

AddHandler me.Closing(byVal frmClosing as Object, _
            ByVal EventData as CancelEventArgs)

But this obviously didn't work.

Hello Woody,

\\\
AddHandler Me.Closing, AddressOf Me.Form1_Closing
.
.
.
Private Sub Form1_Closing( _
    ByVal sender As Object, _
    ByVal e As System.ComponentModel.CancelEventArgs _
)
    MsgBox("Closing")
    e.Cancel = True
End Sub
///

-- or --

\\\
Private Sub Form1_Closing( _
    ByVal sender As Object, _
    ByVal e As System.ComponentModel.CancelEventArgs _
) Handles MyBase.Closing
    MsgBox("Closing")
    e.Cancel = True
End Sub
///

Regards,
Herfried K. Wagner