XpwSetColor can be used to change the foreground colour (as shown in
TEACH RC_GRAPHIC), but I have found no way to change the background
colour (except within the new GO (Graphical Objects) package, which is
not generally available yet).

You can also change the foreground colour of the rc_graphic window by
doing, for example

'red' -> rc_window("foreground");   ;;; NOT in TEACH RC_GRAPHIC!

But this doesn't work, alas

'pink' -> rc_window("background");

There must be a way surely? I tried this code, based on stuff in
GO but it did not work either.

define rc_set_bgcolour(colourstring, widget);
    lvars colourstring, widget, colournumber, widget, oldcolour;

    ;;; remember original colour
    XptValue(widget, XtN foreground) -> oldcolour;

    ;;; find the new integer colour number
    colourstring -> widget("foreground");
    XptValue(widget, XtN foreground) -> colournumber;

    ;;; reinstate old fg colour
    oldcolour -> XptValue(widget, XtN foreground);
    ;;; set new background
    colournumber -> XptValue( widget, XtN background );
enddefine;

/*
;;; test it
lib rc_graphic;

rc_start();

rc_set_bgcolour('green', rc_window);

;;; doesn't work
*/

Any ideas welcome.
Aaron

define rc_set_background(color);
   color -> rc_window("foreground");
   XpwFillRectangle(rc_window, 0, 0, rc_window("width"), rc_window("height"));
enddefine;

Of course, rc_start() may not use this color though I wouldn't be surprised
if:

        'red' -> rc_window("background");
        rc_start();

works...

Jon.

define rc_set_background(colour);
        lvars colour;
        dlocal %rc_window("foreground")% = colour;
   XpwFillRectangle(rc_window, 0, 0, rc_window("width"), rc_window("height"));
enddefine;

So this works

        'black' -> rc_window("foreground");

        rc_set_background('pink');

        rc_drawline(-100,0,0,100);

But if you change the background to white

        rc_set_background('white');

the black line disappears so the line has to be redrawn. This is one of
the advantages of GO. You can change the background colour of a window
and all the objects on it will remain visible if the foreground colour
is different.

Jon went on:

define rc_set_background(colour);
        lvars colour;
        colour -> rc_window("background");
        XpwClearWindow(rc_window);
enddefine;

And this does indeed work. Moreover, it has the advantage that you can
later interrogate rc_window("background"). So this should presumably
be added to LIB RC_GRAPHIC

But I wonder what's going on when you do

        'pink' -> rc_window("background");

and why that doesn't change it? It certainly changes something!

Thanks

Aaron

    XpwSetColor(rc_window, colour) -> XptValue(rc_window, XtN background);

works (with the side effect of setting the foreground colour to be the same -
needs to be reset). But it won't have a visible effect until the next

    rc_clear_window();

or some other "clear" operation.

Colin