LOGO-L> 15-Word Challenge WINNERS
Author Message
LOGO-L> 15-Word Challenge WINNERS

----- LOGO 15-WORD CHALLENGE WINNERS -----

The Challenge:

Write a Logo one-liner using 15 or fewer words,
not counting square brackets and parentheses,
to produce the most beautiful, complex, and
interesting picture.

The winners were chosen based on these criteria:

1. The beauty, complexity, and interestingness
of the picture, and

2. The simplicity of the commands.

I used MSW Logo version 4 to run the one-liners.
MicroWorlds versions of the winners are given at
the end of this message.

I have added "reset" to the beginning of each one-liner
to remind you to reset all modes. You may define "reset"
as a procedure. (Don't count "reset" as a word.)

--- THE GRAND PRIZE (THE GOLDEN TURTLE) ---

Five Rose or Starfish, 8W
Paolo Passaro submitted the original longer
version, and then Julie Clune and he submitted
shorter, simpler versions.

reset repeat 1800 [fd 10 rt repcount + .1]

This is very beautiful and very simple.
This is only EIGHT words!
It is one of the shortest entries in the contest.

There are variations, such as Ten Rose:
reset repeat 3600 [fd 10 rt repcount + .2]

Paolo Passaro provides a general procedure.
It is interesting to figure out the formula.

to roses :l :n :k
local "x
make "x (2*:k-:n)/(2*:n)
repeat 360*:n [fd :l rt repcount+:x]
end
; :l is the step size
; :n is the number of "roses"
; :k is the order

Try this:
cs roses 5 5 3
cs roses 5 7 3
cs roses 5 10 7
cs roses 5 12 5

--- THE "PURE LOGO" PRIZE ---

Dahlia, 14W, David Eisenstat

reset repeat 8 [rt 45 repeat 6 [repeat 90 [fd 2 rt 2] rt 90]]

The 6 can be replaced with 1 to 7 for other flowers.
For numbers greater than 7, the patterns repeat.
The flowers are lovely. I like number 6 best.
This will work without modification in absolutely
all Logo implementations.

--- THE "COMPLEXITY" PRIZE ---

Layers, 15W, Alessio Plebe

reset for [i 0 420] [seth :i repeat :i [fd 2 rt 1] pu home pd]

This is slow, but it has very beautiful and
complex moire patterns.

If your screen is small, let it wrap.
The moire effect isn't as strong if you
try to shrink it.

--- THE "CLASSIC MATH" PRIZE ---

Lissajous variations, 15W, Samuel Kilchenmann

reset repeat 360 [setxy (sin(2 * repcount)) * 150 (sin(3 * repcount)) * 150]
reset repeat 360 [setxy (sin(89 * repcount)) * 150 (sin(179 * repcount)) *
150]
reset repeat 360 [setxy (sin(254 * repcount)) * 150 (sin(201 * repcount)) *
150]
reset repeat 360 [setxy (sin(327 * repcount)) * 150 (sin(66 * repcount)) *
150]

Change the factors to get lots of different designs.

--- THE "RANDOM" PRIZE ---

Pencil Sketch*, 15W, Andrzej Baczynski
(shortened by Yehuda Katz)

reset repeat 5000 [run list item sum 1 random 4 [fd bk rt lt] random 10]

This looks remarkably like a person is sketching with
a pencil. It looks even more like a pencil sketch
if you use PENREVERSE (PX) mode.

The method is very clever.
Can you figure out how it works?

--- THE "POLYGON" PRIZE ---

Penta-octagon*, 15W, M.H. Elhefni

reset for [l 10 80 5] [repeat 5 [repeat 8 [fd :l rt 45] rt 72]

Beautiful "telescoping" polygons.
Change the numbers to get more more designs.

--- THE "ANIMATION" PRIZE ---

Circus* (Ring variation 2), 14W, Olga Tuzova

reset px setpensize [100 100] repeat 1000 [repeat 72 [fd 20 rt 10] rt 90]

This requires PENREVERSE (PX) and a big pen.

This cheerful entry reminds me of circus
jugglers and clowns doing cartwheels.

--- THE "SUBTLE EFFECTS" PRIZE ---

Radar, 11W, Zippi Katz

reset px repeat 1000000 [fd 40 fd 40 bk 80 rt 1]

This requires PENREVERSE (PX).

It looks like a weather radar.

The really interesting part is that the
effect is entirely destroyed if you replace
"fd 40 fd 40" by "fd 80".

--- THE "SURPRISE" PRIZE ---

Square Spiral*, 9W, Yehuda Katz

reset px for [x 1 1000000] [fd :x rt 90]

This requires PENREVERSE (PX).

It seems simple, but it has a suprising effect,
based on WRAP mode and PX mode.
The effect will depend on your screen size.
The effect is strikingly bold with a square screen
and more complex with a non-square screen.

In MSW Logo, you can set the screen size.
Example: c:\logo\logo -h 480 -w 640

--- MICROWORLDS VERSIONS OF THE WINNERS ---

The entries above all use MSW Logo syntax.
Here are MicroWorlds versions of the winners.

Five Rose or Starfish (MicroWorlds version)
reset dotimes [i 1800] [fd 10 rt :i + .1]

Dahlia (unchanged for MicroWorlds)
reset repeat 8 [rt 45 repeat 6 [repeat 90 [fd 2 rt 2] rt 90]]

Layers (MicroWorlds version)
reset dotimes [i 420] [seth :i repeat :i [fd 2 rt 1] pu home pd]
(This is too big, but let it wrap.
The moire effect isn't as strong if you
try to shrink it.)

Lissajous variations (MicroWorlds version)
reset dotimes [i 360] [setpos list (sin(254 * :i)) * 150 (sin(201 * :i)) *
150]

Pencil Sketch (unchanged for MicroWorlds)
reset repeat 5000 [run list item sum 1 random 4 [fd bk rt lt] random 10]

Penta-octagon (MicroWorlds version)
reset dotimes [i 15] [repeat 5 [repeat 8 [fd (10 + (:i * 5)) rt 45] rt 72]

Circus (requires PX)

Radar (requires PX)

Square Spiral (requires PX)

----------

Congratulations to the winners, and
thank you to all the participants!

---------------------------------------------------------------

Mon, 22 Nov 1999 03:00:00 GMT

 Page 1 of 1 [ 1 post ]

Relevant Pages

Powered by phpBB® Forum Software