Is there anyway to draw a circle in a Rich Text Box control and then allow
text to be typed over the circled area?  I'm doing a CD label maker program
and want to use the drawn circle as a guide for placing the label text.

Mike

Thanks for the information on printing the picture box correctly.  It's very
much the same as I have done for Rich Text Box.  The remaining problem with
the Picture Box is that, while I can draw text in it, I don't have any
"built-in" text editing funtionally like that of the Rich Text Box.  It
seems to me that developing even simple text editing in a picture box is a
sizeable task.  But my application really depends on being able to insert
and delete text on a line and being able to select text and change fonts and
sizes.  If  I could just put that circle in the Rich Text Box I have it! :)
Any other thoughts or suggestions?

Thanks,
George

Putting your "circle" in a RichText Box (as you currently seem to favour)
will not really help you, even if you discover how to do it, simply because
it will seriously limit the functionality of your application, especially an
application such as yours that is iontended to allow the user to create CD
labels.

For example, one of the first things that the user will want to do is to
print text on the label in a "circular" fashion, so that the main title, for
example, is printed near the top of the label and follows its curve. He may
also want to position other text near the bottom of the circular label, also
following the curve. He doesn't have to do this, of course, but it would be
nice to give him the facility to do so. Using a Picture Box in conjunction
with a RichText Box, in the way that I have suggested, would allow you to do
this, and you would be able to print the "curved" text into the Picture Box
so that the user could see exactly how it is going to appear on his label.

You could, for example, have one RichText Box for the user to enter the
"top" curved text and another to enable him to enter the "bottom" curved
text. You could have as many other little RichText Boxes as you like, to
allow the user to enter and position "normally aligned" text anywhere he
wants. In fact, if you do not want to give the user the option of "mixing
fonts or colours" in any single text entry (an unusual requirement, anyway)
then you could use standard Text Boxes instead. The user could select or
deselect any of these boxes at will.

Another thing you could do is allow the user to select and size a background
picture, which you could display in the Picture Box beneath the text.

All of this would require a fair bit of coding, but you will find it worth
the effort.

I'm actually working on the approach you suggest right now.  It does seem to
be a practical solution for my needs. Thanks very much for your input.  I
have just one more question: How do you print curved text to the picture
box?  I don't really need to for my use, but I'm interested in how it's
done.

Thanks again,
George

You can, however, write code to draw each character separately, creating a
"rotated font" for each individual character and positioning it using a bit
of code to set the desired position of that character along the perimeter of
a circle. That shpouldn't be too difficult to do, and it will certainly
work.

Just to get you started, here is some code to enable you to draw "rotated
text". The example code is written to print rotated text to the printer
(something which you will obviously have to do when you print your CD label)
but you can easily change it to print to the Picture Box instead. I have
deliberately posted "printer rotated text" rather than "picture box rotated
text" because printing rotated text to the printer is not quite as simple as
printing it to a picture box, and so you will need this code anyway.

Mike

Option Explicit
Private Const LF_FACESIZE = 32
Private Type LOGFONT
    lfHeight As Long
    lfWidth As Long
    lfEscapement As Long
    lfOrientation As Long
    lfWeight As Long
    lfItalic As Byte
    lfUnderline As Byte
    lfStrikeOut As Byte
    lfCharSet As Byte
    lfOutPrecision As Byte
    lfClipPrecision As Byte
    lfQuality As Byte
    lfPitchAndFamily As Byte
    lfFaceName As String * LF_FACESIZE
End Type
Private Declare Function CreateFontIndirect Lib "gdi32" _
Alias "CreateFontIndirectA" (lpLogFont As LOGFONT) As Long
Private Declare Function SelectObject Lib "gdi32" _
(ByVal hdc As Long, ByVal hObject As Long) As Long
Private Declare Function DeleteObject Lib "gdi32" _
(ByVal hObject As Long) As Long
Private Declare Function TextOut Lib "gdi32" Alias _
"TextOutA" (ByVal hdc As Long, ByVal x As Long, ByVal _
y As Long, ByVal lpString As String, ByVal nCount _
As Long) As Long ' or Boolean

Private Sub RotatedText(textstring As String, angle As Long)
' Prints rotated text at the current printer x and y
' coordinates at a specified angle (in tenths of a degree
' in an anti clockwise direction (zero is normal text)
Dim printer_hdc As Long
Dim oldmode As Long, xpix As Long, ypix As Long
Dim log_font As LOGFONT
Dim new_font As Long, old_font As Long
With Printer
xpix = .ScaleX(.CurrentX - .ScaleLeft, .ScaleMode, vbPixels)
ypix = .ScaleY(.CurrentY - .ScaleTop, .ScaleMode, vbPixels)
printer_hdc = .hdc
End With
With log_font
 .lfEscapement = angle
 .lfHeight = (Printer.FontSize * -20) / Printer.TwipsPerPixelY
 .lfFaceName = Printer.FontName & vbNullChar
 If Printer.FontBold = True Then
  .lfWeight = 700
 Else
  .lfWeight = 400
 End If
  .lfItalic = Printer.FontItalic
  .lfStrikeOut = Printer.FontStrikethru
  .lfUnderline = Printer.FontUnderline
 End With
new_font = CreateFontIndirect(log_font)
old_font = SelectObject(printer_hdc, new_font)
TextOut printer_hdc, xpix, ypix, textstring, Len(textstring)
SelectObject printer_hdc, old_font
DeleteObject new_font
End Sub