Private Sub cmdSummary_Click()

    Summary  <--Calling this procedure
End Sub
------------------------------------------
Private Sub Summary(ByVal intTotal As Integer, intUsers As Integer)
'these variables are calculated in another procedure

    frmSummary.Show
    frmSummary.lblTotal = intTotal
    frmSummary.lblUsers = intUsers
    frmSummary.lblAverage = intTotal / intUsers
End Sub
------------------------------------------

===================================================

========================================================

Dim iT1 As Integer
Dim iT2 As Integer

Summary(iT1, iT2)
=======================================

Private Sub cmdSummary_Click()

    Summary
End Sub
-------------------------------------------

Private Sub Calculate()

    Dim intTotal     As Integer
    Dim intUsers     As Integer

    If Not IsNumeric(txtNumber1.Text) Then
        MsgBox "Please Enter a Valid number", vbOKOnly, "Error"
        With txtNumber1
                       .Text = ""
                       .SetFocus
        End With
    ElseIf Not IsNumeric(txtNumber2.Text) Then
        MsgBox "Please Enter a Valid Number.", vbOKOnly, "Error"
        With txtNumber2
                       .Text = ""
                       .SetFocus
        End With
    Else
        intTotal = intTotal + Val(txtNumber1.Text) + Val(txtNumber2.Text)
        intUsers = intUsers + 1
        lblSum.Caption = Val(txtNumber1.Text) + Val(txtNumber2.Text)
        cmdSummary.Enabled = True
        mnuSummary.Enabled = True
    End If
End Sub
---------------------------------------------------------------

Private Sub Summary(ByVal intTotal As Integer, intUsers As Integer)

Try the following in a test project:

Dim iT1 as Integer
Dim iT2 as Integer

iT1 = 6
iT2 = 3

Summary(iT1, iT2)

============================================================================
============

In case you have not yet figured out your problems, let me add the following:

1. - If you want the calculated values of intTotal and intUsers to be available
to other methods and functions in your Form then you will have to declare the
variables at the module level, not in the Sub itself:

Dim intTotal As Integer
Dim intUsers As Integer

Private Sub Calculate()
    If Not IsNumeric(txtNumber1.Text) Then
        MsgBox "Please Enter a Valid number", vbOKOnly, "Error"
        With txtNumber1
                       .Text = ""
                       .SetFocus
        End With
    ElseIf Not IsNumeric(txtNumber2.Text) Then
        MsgBox "Please Enter a Valid Number.", vbOKOnly, "Error"
        With txtNumber2
                       .Text = ""
                       .SetFocus
        End With
    Else
        intTotal = intTotal + Val(txtNumber1.Text) + Val(txtNumber2.Text)
        intUsers = intUsers + 1
        lblSum.Caption = Val(txtNumber1.Text) + Val(txtNumber2.Text)
        cmdSummary.Enabled = True
        mnuSummary.Enabled = True
    End If
End Sub

2. - If you do this, intTotal and intUsers will be automatically available to
your Summary method, so you won't need to use any arguments:

Private Sub Summary
    frmSummary.Show
    frmSummary.lblTotal = intTotal
    frmSummary.lblUsers = intUsers
    frmSummary.lblAverage = intTotal / intUsers
End Sub

3. -  What you will now need is to call the Calculate method to actually
calculate your values, and then the Summary method to use them:

Private Sub cmdSummary_Click()
    Calculate
    Summary
End Sub

4. - Alternatively, you could put the whole thing in the cmdSummary_Click()
event:

Private Sub cmdSummary_Click()
    Dim intTotal As Integer
    Dim intUsers As Integer

    If Not IsNumeric(txtNumber1.Text) Then
        MsgBox "Please Enter a Valid number", vbOKOnly, "Error"
        With txtNumber1
                       .Text = ""
                       .SetFocus
        End With
    ElseIf Not IsNumeric(txtNumber2.Text) Then
        MsgBox "Please Enter a Valid Number.", vbOKOnly, "Error"
        With txtNumber2
                       .Text = ""
                       .SetFocus
        End With
    Else
        intTotal = intTotal + Val(txtNumber1.Text) + Val(txtNumber2.Text)
        intUsers = intUsers + 1
        lblSum.Caption = Val(txtNumber1.Text) + Val(txtNumber2.Text)
        cmdSummary.Enabled = True
        mnuSummary.Enabled = True
    End If
    frmSummary.Show
    frmSummary.lblTotal = intTotal
    frmSummary.lblUsers = intUsers
    frmSummary.lblAverage = intTotal / intUsers
End Sub

Regards,

John..............

When you declare a subroutine with one or more arguments, you are telling VB to supply a
one-to-one mapping of each variable;s memory location between your subroutine (where you
will either be using a value passed into your subroutine from the code calling it; or you
will communicate a calculated value back to the code that called it from your subroutine).

This passageway between the calling code and the subroutine's code is what makes
subroutines so useful. When you provide the argument(s) in the declaration of the
subroutine, you are telling VB to create this passageway where you will either provide
values for the subroutine to process or where you return values for the calling code to
use, or both. If you do not need this passage way, then don't specify the subroutine as
requiring any arguments.

Now, here is where the explanation gets a little murky. You stated that intTotal and
intUsers was being handled elsewhere. By this, I assume you mean they are globally defined
somewhere within your program. First, let me state that you should strive to minimize the
use of globally defined variables. At your present skill level, they will seem quite
seductive -- no matter where you are in your program, you can assign them values and
retrieve values from them -- and on a small program, somewhat manageable. But when you
start writing large programs, they will start to cause you all kinds of maintenance
headaches. That is not to say never use them, there ARE circumstances where their use is
quite helpful, just try not to use them everywhere. Anyway, if I'm correct and the
intTotal and intUsers are global, then the subroutine can see them automatically and you
didn't have to place them in the subroutine's argument list.

Rick

Private Sub1(astring as string)

    astring =astring & "Frost"

End sub

Private Sub2(ByVal astring as string)

    astring =astring & "Frost"
   Print "In Sub2 = " & astring

End sub

Sub Command1_Click

    dim sName as string
    sName = "Robert"
    Sub1 sName
    Print sName
    Sub2 sNme
    Print sName

End Sub

Because sName was passed ByRef to Sub1, the sub changed the string passed
from "Robert" to "Robert Frost". But the subsequent passing of sName to Sub2
generated an undesirable side effect -- it appended the last name, but to
the altered string, resulting in a printout of the double last name. Back in
the calling procedure, because the param to Sub2 was ByVal, sName remained
unaltered.

'printout results
Robert Frost
In Sub2 = Robert FrostFrost
Robert Frost

Note as well that passing a variable enclosed in brackets also creates a
ByVal pass, i.e...

  Sub1 sName             'ByRef pass
  Sub1 ByVal sName   'ByVal pass
  Sub1 (sName)           'ByVal pass

.. but NOT if the Call syntax is used:

  Call Sub1(sName)             'ByRef pass, not ByVal
  Call Sub1(ByVal sName)   'ByVal pass
  Call Sub1((sName))           'ByVal pass, double brackets

'--------------------

Dim result as integer
Dim param as integer

   param = 25
   result = CalcA(param)

Private function CalcA(sDataIn as Integer) as Integer
   sDataIn = sDataIn * 2
   CalcA =sDataIn
Exit Function

Now, in addition to result holding the value 50, param is now equal to 50.
If you later wanted to use param again in another call or method, expecting
its value to be 25, you would now have an error in your program.

'--------------------

So ... for your app, you want:

Private Sub cmdSummary_Click()

   <code to calc values for intUsers/intTotal>
    Summary intTotal, intUsers

End Sub

"Argument not optional" means just that .. you defined the Summary sub to
accept and expect two values to be passed. In your initial code, you passed
none, hence the error.

If the passing of parameters was not mandatory, you would use the Optional
keyword in defining the sub ...

Private Sub Summary(Optional intTotal As Integer, Optional intUsers As
Integer)

This would allow you to call Summary without parameters as you initially
did, but of course the results would be meaningless since Summary has no
knowledge of what intTotal or intUsers was, let alone their value.

--

Randy Birch
MVP Visual Basic

http://www.mvps.org/vbnet/

Please respond only to the newsgroups so all can benefit.