I need help writing a Qbasic modem program, all I want to do is write a
dumb terminal. Anyone know where I could get one please tell me or just
show me one of yours.

Thanx!

Check out the one which is in the Christmas Edition of the Basic Fanzine,
which is now available from SimTel sites.  This terminal will also handle
ANSI to some extent (No split-screen scrolling or screen modifying commands
though!)

--
Cheers,

Ben

------------------====### legal notice ###====-----------------------
Microsoft Network is prohibited from redistributing this work in any
form,in whole or in part.  License to distribute this post is available to
Microsoft for $499.  Posting without permission constitutes an agreement to
these terms.

You should already have this. QB45\EXAMPLES\TERMINAL.BAS.
Here it is in case you lost it. Hope it helps. You should
 be able to modify it to suit your needs.

'---------------------------------------------------
DEFINT A-Z

DECLARE SUB Filter (InString$)

COLOR 7, 1                      ' Set screen color.
CLS

Quit$ = CHR$(0) + CHR$(16)      ' Value returned by INKEY$
                                ' when ALT+q is pressed.

' Set up prompt on bottom line of screen and turn cursor on:
LOCATE 24, 1, 1
PRINT STRING$(80, "_");
LOCATE 25, 1
PRINT TAB(30); "Press ALT+q to quit";

VIEW PRINT 1 TO 23              ' Print between lines 1 & 23.

' Open communications (1200 baud, no parity, 8-bit data,
' 1 stop bit, 256-byte input buffer):
OPEN "COM1:1200,N,8,1" FOR RANDOM AS #1 LEN = 256

DO                              ' Main communications loop.

   KeyInput$ = INKEY$           ' Check the keyboard.

   IF KeyInput$ = Quit$ THEN    ' Exit the loop if the user
      EXIT DO                   ' pressed ALT+q.

   ELSEIF KeyInput$ <> "" THEN  ' Otherwise, if the user has
      PRINT #1, KeyInput$;      ' pressed a key, send the
   END IF                       ' character typed to the modem.

   ' Check the modem. If characters are waiting (EOF(1) is
   ' true), get them and print them to the screen:
   IF NOT EOF(1) THEN

      ' LOC(1) gives the number of characters waiting:
      ModemInput$ = INPUT$(LOC(1), #1)

      Filter ModemInput$        ' Filter out line feeds and
      PRINT ModemInput$;        ' backspaces, then print.
   END IF
LOOP

CLOSE                           ' End communications.
CLS
END
'
' ========================= FILTER ==========================
'     Filters characters in an input string.
' ============================================================
'
SUB Filter (InString$) STATIC

   ' Look for backspace characters and recode them to
   ' CHR$(29) (the LEFT cursor key):
   DO
      BackSpace = INSTR(Instring$, CHR$(8))
      IF BackSpace THEN
         MID$(InString$, BackSpace) = CHR$(29)
      END IF
   LOOP WHILE BackSpace

   ' Look for line-feed characters and remove any found:
   DO
      LineFeed = INSTR(Instring$, CHR$(10))
      IF LineFeed THEN
         InString$ = LEFT$(InString$, LineFeed - 1) + _
                      MID$(InString$, LineFeed + 1)
      END IF
   LOOP WHILE LineFeed

END SUB
'-----------------------------------------------------------
--
Best wishes,
Mervyn Baldwin.

Example program with remarks on virtually every line (but cannot access
COM3 or COM4; also cannot use speed higher than 9600):
ftp://members.aol.com/markkkim/BASIC/BASTerm.bas

-Mark

Come on... I use COM1 for mouse and it makes COM2 useless (on my
computer) so I have to use COM4. Try this library. It's freeware and
remember to thank the author many times over for the great library!!!!
-Azimer

begin 644 qb45mdm2.zip
<uuencoded_portion_removed>
end