I am pretty good at programming in VB but not VBA, and have no idea about
document references.

Can anyone give me any pointers?

Heck, I got one working, but no table.  I tried to use my fav TAB(##)
function to tab over to another tabstop to create the "second column" but it
wasn't working, kept giving me an error about the index not correct?

Dim oFont As Variant
Dim oTable As Table
Dim oRow As Row

Set oTable = ActiveDocument.Tables.Add( _
                Range:=Selection.Range, _
                NumRows:=1, _
                NumColumns:=2)

Set oRow = oTable.Rows.Last

For Each oFont In FontNames
    With oTable.Rows.Last
        .Cells(1).Range.Text = oFont
        .Cells(2).Range.Text = oFont
        .Cells(1).Range.Font.Name = oFont
    End With
    Set oRow = oTable.Rows.Add
Next oFont

-------------------------------------------------------------

Hope this helps.
ibby

Please post replies or follow-ups to the **newsgroup** so that participants
may benefit or contribute.

Try this. It will add text to a document and then convert it into a table.
Sometimes as faster to do it this way around.
'------------------------------------
Dim sFont As Variant
Dim oRng As Range
Dim oTbl As Table

For Each sFont In Application.FontNames
    With Selection
        .Font.Name = sFont
        .TypeText sFont & vbTab & sFont & vbCr
    End With
Next

Set oTbl = ActiveDocument.Range.ConvertToTable _
        (Separator:=wdSeparateByTabs, NumColumns:=2)

oTbl.Sort FieldNumber:=2
oTbl.Columns(2).Select
Selection.Font.Name = "Times New Roman"
Selection.Collapse wdCollapseStart

--
Anna Bohman
Bra Utbildning AB, Sweden