I am just starting out with macros and scripting.  I am not looking
for someone to do the macro or script just some directions that I
might look into.

I am creating some letterhead (who isn't right?) and I want to do a
few things with the letterhead that I am not sure how to go about.
Let me explain a bit with an example.

Example Letter head:

Name of person [drop-down box listing each employee]
Address [text, not a form field]
Phone [text, not a form field]
Direct Phone [this is my question]
Email [another part of the question]

Above is the run down of what I want to display.  The way I want to
execute it is to have the person using the template file
(letterhead.dot) to use the drop down box to pick a name, and then
have the macro, script, whatever fill in the appropriate direct phone
number and email address without any further input from the user.

So my question is how do I go about this?  Should I be reading up on
macros that use arrays or is there something easier that I am missing
with the form fields?  Any Advice would be appreciated.

Thank you
Jeff

What you should be using is a userform.  To get started, see the article
"How to create a Userform" at:

http://www.mvps.org/word/FAQs/Userforms/CreateAUserForm.htm

And here's a bit more advanced information on making use of a listbox or
combobox with multiple columns in it (not all of which need be visible to
the user), but from which the data can be entered into the document when the
user picks one of the items in the box:

The best thing to do is store the client details in a table in a separate
document (which makes it easy to maintain with additions, deletions etc.),
that document being saved as Clients.Doc for the following code.

Then on the UserForm, have a list box (ListBox1) and a Command Button
(CommandButton1) and use the following code in the UserForm_Initialize() and
the CommandButton1_Click() routines

Private Sub UserForm_Initialize()
    Dim sourcedoc As Document, i As Integer, j As Integer, myitem As Range,
m As Long, n As Long
    ' Modify the path in the following line so that it matches where you
saved Suppliers.doc
    Application.ScreenUpdating = False
    ' Open the file containing the client details
    Set sourcedoc = Documents.Open(FileName:="e:\worddocs\Clients.doc")
    ' Get the number or clients = number of rows in the table of client
details less one
    i = sourcedoc.Tables(1).Rows.Count - 1
    ' Get the number of columns in the table of client details
    j = sourcedoc.Tables(1).Columns.Count
    ' Set the number of columns in the Listbox to match
    ' the number of columns in the table of client details
    ListBox1.ColumnCount = j
    ' Define an array to be loaded with the client data
    Dim MyArray() As Variant
    'Load client data into MyArray
    ReDim MyArray(i, j)
    For n = 0 To j - 1
        For m = 0 To i - 1
            Set myitem = sourcedoc.Tables(1).Cell(m + 2, n + 1).Range
            myitem.End = myitem.End - 1
            MyArray(m, n) = myitem.Text
        Next m
    Next n
   ' Load data into ListBox1
    ListBox1.List() = MyArray
    ' Close the file containing the client details
    sourcedoc.Close SaveChanges:=wdDoNotSaveChanges
End Sub

Private Sub CommandButton1_Click()
Dim i As Integer, Addressee As String
Addressee = ""
For i = 1 To ListBox1.ColumnCount
    ListBox1.BoundColumn = i
    Addressee = Addressee & ListBox1.Value & vbCr
Next i
ActiveDocument.Bookmarks("Addressee").Range.InsertAfter Addressee
UserForm2.Hide
End Sub

The Initialize statement will populate the listbox with the data from the
table and then when a client is selected in from the list and the command
button is clicked, the information for that client will be inserted into a
bookmark in the document.  You may want to vary the manner in which it is
inserted to suit our exact requirements, but hopefully this will get you
started.

To make it easy for you, the code has been written so that it will deal with
any number of clients and any number of details about each client.  It
assumes that the first row of the table containing the client details is a
header row.

That should give you something to start with.

Please post any response to the newsgroups for the benefit of others who may
also be following the thread.

Hope this helps,
Doug Robbins - Word MVP