'----- start of code -----
Function fncTrimChars( _
            StringToTrim As String, _
            CharsToTrim As String, _
            Optional ByVal TrimWhere As String = "B", _
            Optional ByVal CompareMethod As Integer = vbBinaryCompare)
_
        As String

    ' Trim leading and/or trailing occurrences of specified characters
from a string.
    '
    ' Arguments are
    '   StringToTrim  - character string to be trimmed
    '   CharsToTrim   - string containing the characters to be
trimmed. Multiple
    '                     characters may be specified;  they will be
considered
    '                     interchangeable and will all be trimmed
    '   TrimWhere     - Optional character to specify where the
t{*filter*} should occur:
    '                     L = on the left
    '                     R = on the right
    '                     B = both left and right (the default)
    '   CompareMethod - Optional integer specifying whether binary
comparison or
    '                     text comparison is used. Default is binary.
Use the
    '                     VB constants vbBinaryCompare and
vbTextCompare to specify
    '                     this option.
    '
    ' fncTrimChars -- Copyright 2002, Dirk Goldgar
    ' License is granted to use this function in your programs so long
as the
    ' copyright notice remains unchanged.

    Dim lngLength As Long
    Dim lngStart As Long
    Dim lngStop As Long

    If Len(TrimWhere) = 0 Then
        TrimWhere = "B"
    End If
    If Not TrimWhere Like "[BLR]" Then
        Err.Raise 5
    End If

    lngLength = Len(StringToTrim)
    If lngLength = 0 Then
        Exit Function
    End If

    If TrimWhere = "B" _
    Or TrimWhere = "L" _
    Then
        For lngStart = 1 To lngLength
            If InStr(1, CharsToTrim, Mid$(StringToTrim, lngStart, 1),
CompareMethod) = 0 _
            Then
                Exit For
            End If
        Next lngStart
    Else
        lngStart = 1
    End If

    If TrimWhere = "B" _
    Or TrimWhere = "R" _
    Then
        For lngStop = lngLength To lngStart Step -1
            If InStr(1, CharsToTrim, Mid$(StringToTrim, lngStop, 1),
CompareMethod) = 0 _
            Then
                Exit For
            End If
        Next lngStop
    Else
        lngStop = lngLength
    End If

    fncTrimChars = Mid$(StringToTrim, lngStart, 1 + lngStop -
lngStart)

End Function
'----- end of code -----

Beware of lines wrapped by the newsreader in the above code.

--
Dirk Goldgar, MS Access MVP
www.datagnostics.com

(please reply to the newsgroup)

Access XP has replace function
some = Replace(some, "_", "")

If I remember corectly in previous versions does not have this function.

So you could create own function
(create public if needed)
Function OwnTrim(stValue As String) As String

    Dim intMax As Integer
    Dim intStart As Integer
    Dim intFound As Integer

    intMax = Len(stValue)
    intStart = intMax - 1

    Do Until intStart = 0
    intFound = InStr(intStart, stValue, "_")
    If intFound > intStart Then Exit Do
    intStart = intStart - 1
    Loop

    stValue = Mid(stValue, 1, intFound - 1)

    OwnTrim = stValue

End Function

--
Posted via http://dbforums.com

--
Dirk Goldgar, MS Access MVP
www.datagnostics.com

(please reply to the newsgroup)