Options.PrintEvenPagesInAscendingOrder = True
    Options.PrintOddPagesInAscendingOrder = False
    ActiveDocument.PrintOut ManualDuplexPrint:=True

Everything is perfect, but i don't know how to reset the printer after this
manual duplex printing.
Any ideas?

You need to save the user's existing settings into variables before you
change them, and then put those values back after the printing is done. Do
it this way:

    Dim oldEven As Boolean, oldOdd As Boolean

    oldEven = Options.PrintEvenPagesInAscendingOrder
    oldOdd = Options.PrintOddPagesInAscendingOrder

    Options.PrintEvenPagesInAscendingOrder = True
    Options.PrintOddPagesInAscendingOrder = False
    ActiveDocument.PrintOut ManualDuplexPrint:=True, _
        Background:=False

    Options.PrintEvenPagesInAscendingOrder = oldEven
    Options.PrintOddPagesInAscendingOrder = oldOdd

When the Background parameter of .PrintOut is False, the macro waits for
printing to finish before executing the next line.

--
Regards,
Jay Freedman
Microsoft Word MVP          FAQ: http://www.mvps.org/word

The ManualDuplexPrinter setting isn't a member of the Options object the way the
Even and Odd properties are, so you can't reset it the same way. The trick is
explained at http://www.mvps.org/word/FAQs/MacrosVBA/ResetPrintToFile.htm -- you
"print" the nonexistent page 0 to change the value. Here's the complete code:

Sub PrintManualDuplex()
    Dim oldEven As Boolean, oldOdd As Boolean

    oldEven = Options.PrintEvenPagesInAscendingOrder
    oldOdd = Options.PrintOddPagesInAscendingOrder

    Options.PrintEvenPagesInAscendingOrder = True
    Options.PrintOddPagesInAscendingOrder = False
    ActiveDocument.PrintOut ManualDuplexPrint:=True, _
        Background:=False

    Options.PrintEvenPagesInAscendingOrder = oldEven
    Options.PrintOddPagesInAscendingOrder = oldOdd
    Application.PrintOut ManualDuplexPrint:=False, _
        Range:=wdPrintRangeOfPages, Pages:="0"
End Sub

--
Regards,
Jay Freedman
Microsoft Word MVP        Word MVP FAQ site: http://www.mvps.org/word